Custom search help extension in SAP Fiori app based on CDS Query

Prerequisite:

You have understanding of how to extend analytical query based Fiori app by adding custom field to analytical query and cube. If not, find out how by following my blog at Extending SAP Fiori app based on CDS Query.

If you understood, adding search help to custom field is not a rocket science. All you have to do is to create a search help view and define it as an association in Cube extension view.

The Setup

In this blog, I will explain with a sample CDS Cube and Query view with custom CDS search help view for the sake of simplicity.

Create sample CDS Cube and Query

Create YANALYTICAL_CUBE in ADT which uses ACDOCA as data source. This serves as Analytical Cube view, which is equivalent to I_GLAccountLineItemCube in Journal Entry Analyzer(F0956). 

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Test analytical cube'
@Analytics: { dataCategory: #CUBE }
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType: { sizeCategory: #XXL, dataClass: #MIXED, serviceQuality: #D }
define view entity YANALYTICAL_CUBE
  as select from acdoca
{
  key rldnr as Ledger,
  key rbukrs as CompanyCode,
  key rbukrs as FiscalYear,
  key belnr as AccountingDocument,
  key docln as LedgerGLLineItem

}

Create YANALYITICAL_QUERY in ADT which uses YANALYTICAL_CUBE as data source. This serves as Analytical Query view, which is equivalent to C_GLLineItemsQ0001 in Journal Entry Analyzer(F0956). 

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Test analytical Query'
@Analytics.query: true
@VDM: {viewType: #CONSUMPTION}
@ObjectModel.usageType: { dataClass: #MIXED, sizeCategory: #XXL, serviceQuality: #D }
@ObjectModel.modelingPattern: #ANALYTICAL_QUERY
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_QUERY ]
define view entity YANALYITICAL_QUERY
  as select from YANALYTICAL_CUBE
{
  Ledger,
  @Consumption.filter: { selectionType: #SINGLE, multipleSelections: true, mandatory: true}  
  @AnalyticsDetails.query.display: #KEY_TEXT
  CompanyCode,
  FiscalYear,
  AccountingDocument,
  LedgerGLLineItem
}

Activate the objects and go to transaction code RSRT in SAP GUI. Enter ‘2CYANALYITICAL_QUERY’ and execute. You see that annotation ‘@Consumption.filter’ made Company code as filter but there is no search help available.

Create CDS search help view

Create YANALYITICAL_ValueHelp as CDS search help view that fetches Company Code master table(t001). The view offers just two fields, company code(bukrs) and company code text(butxt ), which are all the information needed to display in search help.

Here the annotation ‘@Semantics.text: true’ defines butxt as text field and annotation ‘@ObjectModel.text.element: [‘Description’]’ tells bukrs that its text field is Description and they are to be shown in the search help alongside the code.

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'search help'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
    serviceQuality: #A,
    sizeCategory: #S,
    dataClass: #CUSTOMIZING
}
define view entity YANALYITICAL_ValueHelp
  as select from t001
{
      @Search.defaultSearchElement: true
      @ObjectModel.text.element: ['Description']
  key bukrs as Code,
      @Semantics.text: true
      butxt as Description
}

Activate the CDS search view. Then add this view as association in CDS cube view. Add the below highlighted lines. This is telling CompanyCode field that it can use whatever information defined in YANALYITICAL_ValueHelp, which in our case is company code master data information. Activate the change in CDS cube view. 

define view entity YANALYTICAL_CUBE
  as select from acdoca

  association [0..1] to YANALYITICAL_ValueHelp      as _CCValueHelp      on $projection.CompanyCode = _CCValueHelp.Code

{
  key rldnr as Ledger,
  @ObjectModel.foreignKey.association: '_CCValueHelp'
  key rbukrs as CompanyCode,
  key rbukrs as FiscalYear,
  key belnr as AccountingDocument,
  key docln as LedgerGLLineItem,
  
  _CCValueHelp
}

Go to RSRT and execute the query again. Now you will be able to see search help is available for company code, which display all the code and text information from Company Code master table(t001). Make sure to switch to Key and text view if the code is not shown.

How to apply this in extending Fiori app

As described in the prerequisite blog post Extending SAP Fiori app based on CDS Query, the structure of the app is based on analytical query and cube. If you need to add search help for your custom fields added in extension view for I_GLAccountLineItemCube, create search help views for those fields first. Then define associations and use them in extension view of I_GLAccountLineItemCube as the exercise we did in this blog.

By CDS query(Embedded Analytics) based standard report